許多玩家在魔獸世界懷舊服中是不是覺得操作比較繁瑣呢？特別是奶這種角色要處理的事情非常的多，很多時(shí)候都按不來，不過官方也是在游戲內(nèi)置了宏的設(shè)置，接下來小編就帶來了一些圣騎士的一鍵宏推薦。

魔獸世界懷舊服圣騎士一鍵宏推薦

1.[祝福]點(diǎn)擊或鍵盤按擊為目標(biāo)施放強(qiáng)效智慧祝福，為智慧祝福。點(diǎn)擊或鍵盤按擊為目標(biāo)施放強(qiáng)效力量祝福，為力量祝福。<鼠標(biāo)左鍵>點(diǎn)擊或鍵盤按鍵為目標(biāo)施放強(qiáng)效王者祝福，<鼠標(biāo)右鍵>為王者祝福。

#showtooltip

/cast [mod:ctrl,button:1]強(qiáng)效智慧祝福

/cast [mod:ctrl,button:2]智慧祝福

/cast [mod:shift,button:1]強(qiáng)效力量祝福

/cast [mod:shift,button:2]力量祝福

/cast [button:1]強(qiáng)效王者祝福

/cast [button:2]王者祝福

== 圣騎士日常祝福還有光明和拯救，游戲?qū)Ｓ檬髽?biāo)還有鍵位的可以繼續(xù)加入綁定(只要不超過255個(gè)字符即可)。這里輔助控制鍵還有Alt鍵，因?yàn)樽晕沂┓ǖ哪J(rèn)快捷鍵就是Alt鍵。大家又習(xí)慣默認(rèn)開啟自動(dòng)自我施法，為避免沖突，所以本宏沒有加入。有意的可自行加入。

== 這是一種利用組合鍵施放法術(shù)的宏。優(yōu)點(diǎn)是把眾多BUFF集合到一個(gè)圖標(biāo)，可自己根據(jù)情況為目標(biāo)施放不同的大小BUFF。缺點(diǎn)是需提前選定要施放BUFF的目標(biāo)。在團(tuán)本或野外通常我們都是鼠標(biāo)點(diǎn)選目標(biāo)，此宏還需要鼠標(biāo)挪回圖標(biāo)位置施放，比較繁瑣低效。處于5人小隊(duì)時(shí)，可以左手按鍵F1到F5選擇隊(duì)友，再配合此宏能稍快捷些。

可以把此宏按不同祝福分解為多個(gè)宏。例如：

2.[王者]點(diǎn)擊直接施放強(qiáng)效王者祝福，按住Ctrl鍵則施放王者祝福

#showtooltip [mod:ctrl]王者祝福;強(qiáng)效王者祝福

/cast [mod:ctrl,help,nodead]王者祝福;[help,nodead]強(qiáng)效王者祝福

提高點(diǎn)效率，這回加入鼠標(biāo)指向：

3.[王者]點(diǎn)擊向鼠標(biāo)指向非死亡友好目標(biāo)施放強(qiáng)效祝福，無鼠標(biāo)指向則為當(dāng)前所選非死亡友好目標(biāo)施放強(qiáng)效祝福，鼠標(biāo)指向、選定目標(biāo)為非友好目標(biāo)或無時(shí)則對自己施放強(qiáng)效王者祝福。同等情況按住Ctrl鍵則施放普通王者祝福

#showtooltip 強(qiáng)效王者祝福

/cast [mod:ctrl,@mouseover,help,nodead][mod:ctrl,help,nodead][mod:ctrl]王者祝福;[@mouseover,help,nodead][help,nodead][]強(qiáng)效王者祝福

還能再提高效率嗎？看看下面這個(gè)：

4.[王者]鼠標(biāo)指向?yàn)閳F(tuán)隊(duì)隊(duì)友則施放強(qiáng)效祝福，鼠標(biāo)指向?yàn)榉顷?duì)友友好目標(biāo)則施放普通祝福，無鼠標(biāo)指向則為當(dāng)前所選非死亡友好目標(biāo)施放普通祝福，無任何目標(biāo)或鼠標(biāo)指向自己則對自己施放普通祝福，無論何種情況按住Alt鍵為自己施放強(qiáng)效祝福。

#showtooltip 強(qiáng)效王者祝福

/cast [mod:alt,@player][@mouseover,group,help,nodead]強(qiáng)效王者祝福;[@mouseover,help,nogroup:party,nodead][]王者祝福

說明:眾所周知，騎士的普通祝福可以對友好玩家施放，強(qiáng)效祝福只能為團(tuán)隊(duì)中的隊(duì)友施放，所以本宏利用此點(diǎn)將兩者合二為一。同時(shí)還加入了鼠標(biāo)指向，令操作更加的便捷。

建議依此為模板，將每種祝福做一個(gè)宏。

下面展示高度整合的終極祝福宏：

5.[光力智]當(dāng)鼠標(biāo)指向?yàn)閳F(tuán)隊(duì)隊(duì)友時(shí)只為其施放強(qiáng)效祝福，鼠標(biāo)指向?yàn)榉菆F(tuán)隊(duì)隊(duì)友時(shí)為其施放普通祝福。如無鼠標(biāo)指向或鼠標(biāo)指向非友好目標(biāo)時(shí)，則直接對當(dāng)前所選目標(biāo)施放普通祝福。

#showtooltip

/cast [mod:ctrl,@mouseover,group,help]強(qiáng)效力量祝福;[mod:ctrl,@mouseover,help][mod:ctrl,help]力量祝福;[mod:shift,@mouseover,group,help]強(qiáng)效智慧祝福;[mod:shift,@mouseover,help][mod:shift,help]智慧祝福;?[@mouseover,group,help]?強(qiáng)效光明祝福;?[@mouseover,help]?[help]光明祝福

6.[王拯庇]

#showtooltip

/cast [mod:ctrl,@mouseover,group,help]強(qiáng)效拯救祝福;[mod:ctrl,help]拯救祝福;[mod:shift,@mouseover,group,help]強(qiáng)效庇護(hù)祝福;[mod:shift,@mouseover,help][mod:shift,help]庇護(hù)祝福;?[@mouseover,group,help]?強(qiáng)效光明祝福;[mod:alt,@player]?[@mouseover,help]?[help]王者祝福

缺點(diǎn)：只加入了按住Alt鍵為自己加強(qiáng)效王者，鼠標(biāo)指向自己或選定自己才能為自己施放普通祝福。不能利用Alt鍵，選定友好目標(biāo)時(shí)強(qiáng)制為自己施放其他祝福。還有就是沒有隊(duì)伍時(shí)，無法為自己加其它強(qiáng)效祝福。

*提示：[]里邊是為此宏起的名稱，當(dāng)宏圖標(biāo)放入動(dòng)作條時(shí)，只能顯示出名稱的前2個(gè)漢字或4個(gè)英文字母。所以為宏起個(gè)簡潔的名稱可以起到準(zhǔn)確提示的作用。

== 還需要注意的是這種綁定了Ctrl、Shift、Alt等組合鍵不要和游戲默認(rèn)按鍵沖突，否則宏無法執(zhí)行。例如： 是第一個(gè)宏物技能，為第一個(gè)動(dòng)作條。把此宏放在1鍵上則無法正常執(zhí)行。

網(wǎng)上能搜到根據(jù)職業(yè)判斷加力量還是智慧的腳本，在這里我就不放出來了。以上不同的宏適合不同的情況和風(fēng)格，具體喜歡哪個(gè)自己選擇。我個(gè)人推薦第四個(gè)。

教學(xué)：#showtooltip非常好用的圖標(biāo)顯示及提示命令，和“?”配合使用。

[mod:ctrl/shift/alt]指認(rèn)輔助鍵

[button:1/2/...]指認(rèn)按鍵。1為鼠標(biāo)左鍵或鍵盤按擊，2為鼠標(biāo)右鍵。多按鍵鼠標(biāo)還可以往后綁定。

[@mouseover]?鼠標(biāo)指向

[group]團(tuán)隊(duì)隊(duì)友

[help]友好目標(biāo)(這里省略了一句exists?判斷目標(biāo)存在的意思，指認(rèn)友好目標(biāo)就確定存在了)

/cast施放技能命令 中文格式為?/施放

7.[正義]釋放正義圣印的同時(shí)，開始近戰(zhàn)攻擊。網(wǎng)上最常見的宏

#showtooltip 正義圣印

/startattack

/cast 正義圣印

優(yōu)點(diǎn)：節(jié)省近戰(zhàn)攻擊按鍵及操作，同時(shí)避免誤操作停止近戰(zhàn)攻擊

缺點(diǎn)：萬一遇到需要近戰(zhàn)停手時(shí)，只能遠(yuǎn)離近戰(zhàn)攻擊范圍，或轉(zhuǎn)身、或清除當(dāng)前目標(biāo)。

適用：正義圣印適合單手快速武器打傷害，通常為小號出命令圣印前升級打怪使用。還有一個(gè)好處就是學(xué)習(xí)高等級技能免除拖動(dòng)替換。

== 根據(jù)不同場合需要可更改為其他圣印。小號使用慢速雙手武器或練習(xí)升級武器技能，掛十字軍圣印。懲戒騎掛命令圣印。比如消耗戰(zhàn)或血量有壓力時(shí)，掛光明圣印近戰(zhàn)砍怪回血。奶騎在團(tuán)本中，藍(lán)已耗盡或治療無壓力時(shí)，通常掛著智慧圣印去近戰(zhàn)砍怪回藍(lán)。

拓展：在?/cast 命令圣印?此行之上加一行?/cast 審判?因?yàn)閷徟胁徽加肎CD，所以可審判同時(shí)掛圣印。(懲戒騎常用，綁命令圣印，審判同時(shí)掛命令圣印平砍，DPS最大化)

教學(xué)：/startattack為開始近戰(zhàn)攻擊 與系統(tǒng)自帶的攻擊按鍵不同是，再按一次也不會(huì)停止攻擊。/stopattack為停止近戰(zhàn)攻擊。

也可以把多個(gè)圣印整合到一起：

8.[圣印]默認(rèn)命令圣印，按住Ctrl為十字軍圣印，Ctrl+鼠標(biāo)右鍵為正義圣印，按住Shift為智慧圣印，Shift+鼠標(biāo)右鍵為光明圣印，按住Alt為1級命令圣印，按住Alt+鼠標(biāo)右鍵為公正圣印。<本人使用的宏>

#showtooltip

/startattack

/cast [mod:ctrl,button:1]十字軍圣印

/cast [mod:ctrl,button:2]正義圣印

/cast [mod:shift,button:1]智慧圣印

/cast [mod:shift,button:2]光明圣印

/cast [mod:alt,button:1]命令圣印(等級 1)

/cast [mod:alt,button:2]公正圣印

/cast 命令圣印

說明：一個(gè)圖標(biāo)整合所有圣印。喜歡的自己可以根據(jù)使用情況調(diào)換圣印位置。

優(yōu)點(diǎn)：多個(gè)圣印綁定在一個(gè)鍵位，且圣印藍(lán)夠就能用，不用考慮CD冷卻的問題。

拓展：也適用于騎士的光環(huán)甚至生活專業(yè)技能(比如鍛造、工程和采集等)。把?/startattack去掉，更改技能名稱即可。

9.[上馬]非戰(zhàn)斗中則召喚千金馬，戰(zhàn)斗中則釋放審判。<本人使用的宏>

#showtooltip [nocombat]召喚戰(zhàn)馬(召喚);[combat]審判

/cast [nocombat]召喚戰(zhàn)馬(召喚);[combat]審判

說明：沒有加入下馬/dismount是因?yàn)榘惭b了自動(dòng)起立、下馬插件。否則好多宏都要加入比較繁瑣。

優(yōu)點(diǎn)：節(jié)省一個(gè)鍵位，且審判和上馬都是高頻率使用技能，放在同一個(gè)高頻鍵位方便快捷高效(本人放在4鍵)。

缺點(diǎn)：無法主動(dòng)審判起手進(jìn)入戰(zhàn)斗(此種情況極少，所以本宏很實(shí)用)。

適用：日常及PVE。

拓展：PVP需審判起手可將審判前[combat]刪除。需注意掛有圣印時(shí)，當(dāng)前所選目標(biāo)不要為被動(dòng)敵對目標(biāo)(黃名怪)或中立目標(biāo)，或以上目標(biāo)不在審判的10碼范圍內(nèi)。否則容易意外審判進(jìn)入戰(zhàn)斗。

== 還有部分人弄了熊怪變身，需取消變身才能上馬，則在上面加一行/cancelaura 熊怪形態(tài)

== PVE中還可以在審判上一行加入一行?/startattack即開始近戰(zhàn)攻擊。需要再注意一點(diǎn)：上馬時(shí)，面前近戰(zhàn)范圍內(nèi)不能有被動(dòng)敵對目標(biāo)(黃名怪)或中立目標(biāo)。否則容易意外砍怪進(jìn)入戰(zhàn)斗。

== 也可以將上馬和其他不常用的技能綁定在一個(gè)宏內(nèi)，將審判替換為該技能名即可。比如十字軍、公正圣印等。上馬也可以和其它對敵對目標(biāo)施放又不常用的技能組合綁定，比如驅(qū)邪術(shù)，憤怒之錘，制裁等(但野外情況復(fù)雜，有時(shí)需要驅(qū)邪開怪，遇到敵對很可能要制裁起手或憤怒收割。而審判不好和其它技能綁定，所以最終考慮將兩者合并)。不推薦綁定增益技能是因?yàn)槊搼?zhàn)后很可能和日常操作沖突。(比如脫戰(zhàn)后需要治療，驅(qū)散或救人加BUFF)。在此鄙視一下每回上下馬還喊話的人。/玩笑

== 有些人會(huì)選擇把跑路神器棍子上的胡蘿卜也加入到宏里，加入一句/equipslot [mounted] 13 石楠之環(huán);[nomounted]13 棍子上的胡蘿卜即可(唯一麻煩就是下馬也需要按下此宏將飾品按回來。也可以利用飾品管理插件實(shí)現(xiàn)。還有追求極速的想把駙魔騎乘的手套還有加裝馬刺的靴子也換上。換飾品和裝備用宏都能實(shí)現(xiàn)(下面給大家貼出來)，就是更換裝備需改動(dòng)宏有點(diǎn)繁瑣，利用一鍵換裝插件再綁定個(gè)快捷鍵會(huì)比較簡便快捷。

教學(xué)：[combat]判斷為戰(zhàn)斗狀態(tài)中?[nocombat]非戰(zhàn)斗狀態(tài)中，即脫戰(zhàn)。

10.[跑馬]每行前面的是輸出裝備，后面的是加速裝備

#showtooltip 召喚戰(zhàn)馬(召喚)

/equipslot [mounted] 13 石楠之環(huán);[nomounted] 13 棍子上的胡蘿卜

/equip [mounted] 輸出手套名稱;[nomounted] 加速手套名稱

/equip [mounted] 輸出靴子名稱;[nomounted] 加速靴子名稱

/cast [nocombat]召喚戰(zhàn)馬(召喚)

/dismount [mounted]

教學(xué)：/equipslot將裝備在指定位置 13，14依次為第一，第二飾品位

/equip直接裝備

[mouted]判斷為騎行狀態(tài)中

11.[救錘]當(dāng)非戰(zhàn)斗狀態(tài)時(shí)，對鼠標(biāo)指向已死亡友好目標(biāo)施放救贖，無鼠標(biāo)指向則直接對當(dāng)前所選死亡友好目標(biāo)救贖，或施放救贖后點(diǎn)選尸體復(fù)活。如鼠標(biāo)指向?yàn)閿硨δ繕?biāo)時(shí)則對其施放憤怒之錘，無鼠標(biāo)指向直接向當(dāng)前敵對目標(biāo)施放憤怒之錘。<本人使用的宏>

#showtooltip [help]救贖;[harm]憤怒之錘

/cast [@mouseover,help,dead,nocombat][help,dead,nocombat]?[@none,nocombat]?救贖;[@mouseover,harm,nodead][harm,nodead]憤怒之錘

說明：日常脫戰(zhàn)救人和斬殺不沖突，所以綁定在一起節(jié)省一個(gè)鍵位及圖標(biāo)。其實(shí)救人本來就是脫戰(zhàn)才能對死亡友好目標(biāo)使用，不需要加入[help,dead,nocombat]判斷命令,還有憤怒之錘中的[harm,nodead]都不影響宏的執(zhí)行。加入是為了避免操作時(shí)語音提示：我還無法使用這個(gè)法術(shù)。如果編寫宏的字?jǐn)?shù)過多超出255字符限制，可將其去除。

優(yōu)點(diǎn)：將救人和收割綁定到一起，還加入了鼠標(biāo)指向。

拓展：因救贖需要非戰(zhàn)斗狀態(tài)下對死亡友好目標(biāo)使用，所以可以和其他對存活敵對目標(biāo)施放的技能組合在一起，比如制裁之錘，驅(qū)邪術(shù)等。(通常脫戰(zhàn)后，其他對存活友好目標(biāo)施放的技能比如清潔術(shù)，祝福，治療等等，此類操作和救人容易沖突，所以不推薦綁定在一起。)也可以加入救人喊話使用。

教學(xué)：[harm]目標(biāo)敵對，絕大多數(shù)情況也可用[nohelp]表示

[dead]目標(biāo)死亡 同理[nodead]表示目標(biāo)存活

[@none]?目標(biāo)為無 有時(shí)隊(duì)友死亡已釋放尸體，需要先按救贖再用鼠標(biāo)點(diǎn)擊尸體。宏里用此命令才能實(shí)現(xiàn)。

12.[清邪]當(dāng)鼠標(biāo)指向?yàn)榇婊钣押媚繕?biāo)時(shí)對其施放清潔術(shù)，無鼠標(biāo)指向時(shí)對所選友好目標(biāo)施放清潔術(shù)，無目標(biāo)時(shí)對自己施放清潔術(shù)。也可按住ALT鍵無論目標(biāo)為何強(qiáng)行自我清潔。當(dāng)鼠標(biāo)指向?yàn)閿硨δ繕?biāo)時(shí)對其施放驅(qū)邪術(shù)，無鼠標(biāo)指向直接向當(dāng)前敵對目標(biāo)施放驅(qū)邪術(shù)。<本人使用的宏>

#showtooltip [help]清潔術(shù);[harm]驅(qū)邪術(shù)

/cast [mod:alt,@player][@mouseover,help,nodead][help,nodead][]清潔術(shù);[@mouseover,harm,nodead][harm,nodead]驅(qū)邪術(shù)

說明：因驅(qū)邪術(shù)只能對亡靈及惡魔目標(biāo)使用，適用情況較少。所以和清潔術(shù)綁定在一起。

優(yōu)點(diǎn)：節(jié)省一個(gè)鍵位，放在同一個(gè)高頻鍵位方便快捷高效。

缺點(diǎn)：當(dāng)身上有DEBUFF需要驅(qū)散，且敵對為亡靈或惡魔目標(biāo)時(shí)。只能先驅(qū)散，再輸出。(目標(biāo)為亡靈或惡魔的情況較少，而惡魔亡靈放毒的時(shí)候也較少，所以本宏比較實(shí)用)若在意此點(diǎn)，也可將清潔術(shù)前的[]刪掉。但需目標(biāo)為自己或按Alt鍵才能為自己驅(qū)散。自行取舍吧。

教學(xué)：@player代表指定目標(biāo)為玩家自己

13.[圣光]鼠標(biāo)指向非死亡友好目標(biāo)時(shí)對其治療，無鼠標(biāo)指向時(shí)對所選非死亡友好目標(biāo)治療，無鼠標(biāo)指向且當(dāng)前目標(biāo)為敵對時(shí)為其目標(biāo)(我方友好)治療，無鼠標(biāo)指向也無當(dāng)前目標(biāo)時(shí)對自己治療(需開啟自動(dòng)自我施法)。也可按住Alt鍵無論目標(biāo)為何強(qiáng)行自我治療。

#showtooltip 圣光術(shù)

/StopCasting

/cast [mod:alt,@player][@mouseover,help,nodead][help,nodead][@targettarget,help,nodead][]圣光術(shù)

說明：這里需要講解一下操作，加入鼠標(biāo)指向治療可以應(yīng)對絕大多數(shù)情況。我用奶騎團(tuán)本都是選定主T為目標(biāo)，當(dāng)主T血量穩(wěn)定的時(shí)候，利用鼠標(biāo)指向?yàn)槠渌酥委煛．?dāng)遇到某些BOSS需要不停換T的時(shí)候就很繁瑣，需要顯示目標(biāo)的目標(biāo)的目標(biāo)(主T--BOSS--當(dāng)前T)，然后鼠標(biāo)時(shí)刻準(zhǔn)備對準(zhǔn)他治療。這時(shí)可以把當(dāng)前目標(biāo)換成BOSS，這樣直接治療目標(biāo)的目標(biāo)(BOSS---當(dāng)前T)。

還加入了打斷施法，可以快速打斷讀條再重新治療。適合根據(jù)BOSS技能反復(fù)預(yù)讀治療。

優(yōu)點(diǎn)：方便快捷團(tuán)本治療，節(jié)省鼠標(biāo)點(diǎn)選隊(duì)友時(shí)間。靈活應(yīng)對各種環(huán)境狀況。

缺點(diǎn)：默認(rèn)只能使用最大等級圣光術(shù)，不能選擇技能等級。

適用：最適合群體PVP，也適合日常PVE。

拓展：此宏也適用于圣光閃現(xiàn)或神圣震擊還有清潔術(shù)，更改技能名稱即可。也可以利用組合鍵，將其整合到一起。例如：

14.

/StopCasting

/cast [mod:ctrl,@mouseover,help,nodead][mod:ctrl,help,nodead][mod:ctrl,@targettarget,help,nodead][mod:ctrl]圣光閃現(xiàn);[mod:shift,@mouseover,help,nodead][mod:shift,help,nodead][mod:shift]神圣震擊;[@mouseover,help,nodead][help,nodead][@targettarget,help,nodead][]圣光術(shù)

教學(xué):target?目標(biāo)

targettarget?目標(biāo)的目標(biāo)

15.[神震]神恩+神圣震擊 可鼠標(biāo)指向。

#showtooltip 神恩術(shù)

/StopCasting

/cast 神恩術(shù)

/cast [mod:alt,@player][@mouseover,help,nodead][help,nodead][]神圣震擊

說明：因?yàn)樯穸餍g(shù)不占GCD，所以可和治療技能綁定同時(shí)施放。兩個(gè)技能冷卻時(shí)間不能全在圖標(biāo)處直觀顯示，需搭配WA等技能冷卻插件配合使用。

適用：重要隊(duì)友危急抬血用。奶騎團(tuán)本必備

16.[多圣]效果同上邊的圣光宏，不同是此宏加入可選擇預(yù)告設(shè)置好的技能等級施放。默認(rèn)為頂級圣光，按ctrl鍵為4級圣光，按shift鍵為7級圣光。<本人使用的宏>

#showtooltip 圣光術(shù)

/StopCasting

/cast [mod:ctrl,@mouseover,help][mod:ctrl,help][mod:ctrl,@targettarget,help,nodead][mod:ctrl]圣光術(shù)(等級 4);[mod:shift,@mouseover,help][mod:shift,help][mod:shift,@targettarget,help,nodead][mod:shift]圣光術(shù)(等級 7);[mod:alt,@player]?[@mouseover,help]?[help][@targettarget,help,nodead][]圣光術(shù)

優(yōu)點(diǎn)：方便快捷團(tuán)本治療，節(jié)省鼠標(biāo)點(diǎn)選隊(duì)友時(shí)間。還增加了不同等級的治療術(shù)，靈活應(yīng)對各種環(huán)境狀況。我正在使用的宏。將其放置在鼠標(biāo)滾輪，配合左手按組合鍵，快速反應(yīng)不影響走位

缺點(diǎn)：只能用Alt鍵強(qiáng)行用頂級圣光術(shù)自我治療。

適用：尤其適合團(tuán)本及日常PVE

拓展：也適用于圣光閃現(xiàn)，更換技能名稱和等級即可。

17.[圣療]立即停止當(dāng)前施法，當(dāng)鼠標(biāo)指向?yàn)榇婊钣押媚繕?biāo)時(shí)對其施放圣療術(shù)，無鼠標(biāo)指向時(shí)直接對所選存活友好目標(biāo)施放圣療術(shù)。按住ALT鍵則無視任何目標(biāo)對自己施放圣療術(shù)。

#showtooltip 圣療術(shù)

/StopCasting

/cast [mod:alt,@player][@mouseover,help,nodead][help,nodead]圣療術(shù)

說明：為了最快速的反應(yīng)，在施放圣療術(shù)之前加入了/StopCasting暫停當(dāng)前施法。不加入的話，經(jīng)常是正在圣光讀條，發(fā)現(xiàn)MT瞬間血絲到底，必須先移動(dòng)一下停止當(dāng)前施法才能施放圣療。

還有一種情況是正要圣療時(shí)隊(duì)友暴斃，開啟了自動(dòng)自我施法的時(shí)候，圣療直接給了自己。不僅浪費(fèi)CD非常長的救命技能，還會(huì)僅剩少量的藍(lán)。

優(yōu)點(diǎn)：最快速圣療隊(duì)友，且不會(huì)因隊(duì)友暴斃而誤將圣療加給自己。

缺點(diǎn)：當(dāng)遇到血量不足需對自己施放時(shí)，需將鼠標(biāo)指向自己，或點(diǎn)選自己，或按Alt鍵。(若在意此點(diǎn)，可在圣療術(shù)前加[]，但如此就失去了此宏前面的優(yōu)點(diǎn))。

適用：團(tuán)本PVE。很明顯不適用于插旗單P

拓展：也適用于保護(hù)祝福，自由祝福，更換技能名稱即可。可以加入喊話。也可以利用組合鍵，將其整合到一起:

18.[保圣自]立即停止當(dāng)前施法，當(dāng)鼠標(biāo)指向?yàn)榇婊钣押媚繕?biāo)時(shí)對其施放保護(hù)，無鼠標(biāo)指向時(shí)直接對存活所選友好目標(biāo)施放保護(hù)。鼠標(biāo)指向及所選目標(biāo)為敵對目標(biāo)或無時(shí)對自己施放保護(hù)。按住Ctrl鍵則施放圣療，按住Shift鍵則為自由。<本人使用的宏>

#showtooltip

/StopCasting

/cast [mod:ctrl,@mouseover,help,nodead][mod:ctrl,help,nodead]圣療術(shù);[mod:shift,@mouseover,help,nodead][mod:shift,help,nodead][mod:shift]自由祝福;[@mouseover,group,help,nodead][group,help,nodead]保護(hù)祝福

說明：圣療術(shù)、保護(hù)和上一個(gè)宏一樣選擇不能默認(rèn)自我施放，需鼠標(biāo)指向或選擇自己(需要的話圣療術(shù)前面加[mod:ctrl],保護(hù)前面加[])。自由可以，但需要鼠標(biāo)指向、所選目標(biāo)為非友好目標(biāo)或無目標(biāo)或目標(biāo)為自己。

哪個(gè)技能需要按Alt鍵強(qiáng)制自我施法可以在技能前加一條[mod:alt,@player]

優(yōu)點(diǎn)：多個(gè)技能綁定一起，鼠標(biāo)指向快速反應(yīng)。

缺點(diǎn)：圖標(biāo)不直觀，需一段時(shí)間熟悉。技能冷卻時(shí)間不能全在圖標(biāo)處直觀顯示，需搭配WA等技能冷卻插件配合使用。

教學(xué)：在這里強(qiáng)調(diào)一下[help,nodead][]和[help,nodead]還有[]的區(qū)別。[]里邊沒有指認(rèn)目標(biāo)，包括當(dāng)前目標(biāo)或無目標(biāo)多種情況。所以[help,nodead][]也可以簡化為[]。而[help,nodead]則指認(rèn)當(dāng)前目標(biāo)，所以圣療術(shù)才得以失去目標(biāo)也不會(huì)施放在玩家自己身上。

19.[制裁]立即停止當(dāng)前施法，當(dāng)鼠標(biāo)指向?yàn)閿硨δ繕?biāo)時(shí)對其制裁，無鼠標(biāo)指向直接向當(dāng)前敵對目標(biāo)制裁。<本人使用的宏>

#showtooltip 制裁之錘

/StopCasting

/cast [@mouseover,harm,nodead][harm,nodead]制裁之錘

適用：群體PVP 小隊(duì)PVE

拓展：也適用于懲戒騎的懺悔。也可以利用組合鍵，將其整合到一起。

20.[奉獻(xiàn)]立即停止當(dāng)前施法，施放奉獻(xiàn)。按住alt則施放1級奉獻(xiàn)。網(wǎng)上最常見的宏。<本人使用的宏>

#showtooltip 奉獻(xiàn)

/StopCasting

/cast [mod:alt]奉獻(xiàn)(等級 1);奉獻(xiàn)

說明：這里的輔助按鍵可以設(shè)置為Ctrl或Shift。因?yàn)樽晕沂┓旖萱I默認(rèn)為Alt鍵，所以其他可以對自己施放的增益法術(shù)(比如祝福、治療、驅(qū)散)都綁定為其他鍵，而這類只能對敵對目標(biāo)生效的技能輔助都設(shè)置為Alt鍵以做區(qū)分。

適用：多用于騎士單刷副本控藍(lán)，更多時(shí)候適用于和賊PVP。這里就不得不提到一個(gè)網(wǎng)上常見的騎士抓賊宏：

21.[抓賊]自動(dòng)鎖定10碼之內(nèi)的敵對目標(biāo)，如果身上有圣印則直接對其審判。

/targetenemy

/script SetCVar("targetNearestDistance",10)

/cast 審判

說明：沒有辦法，騎士是出了名的手短腳短。10碼已經(jīng)是最遠(yuǎn)的審判距離了，所以只能限制鎖定范圍。

適用：沒錯(cuò)，也許你們也想到了。這個(gè)宏再加上面的奉獻(xiàn)宏也可用于爭搶刷新的任務(wù)怪。所以我一個(gè)PVP菜鳥才敢放出來。(想當(dāng)初懷舊開服，人比怪多。本人就是靠此宏搶怪才得以逃脫人山人海)

22.[余藍(lán)]只有在有隊(duì)伍時(shí)，喝水并說出當(dāng)前藍(lán)量百分比。如需沒有隊(duì)伍也可通報(bào)，可將?/stopmacro [nogroup:party]?此行刪掉。此宏是網(wǎng)上借用的。

#showtooltip

/use 魔法晶水

/use 魔法甜面包

/use 晨露酒

/use 魔法蘇打水

/stopmacro [nogroup:party]

/run c=string.format("%d", UnitPower("player")/ UnitPowerMax("player")*100) SendChatMessage(c.."% 的法力剩余", "say",nil, 1)

23.[余血]只有在有隊(duì)伍時(shí)，吃面包并在隊(duì)伍中說出當(dāng)前血量百分比。如需沒有隊(duì)伍也可通報(bào)，可將?/stopmacro [nogroup:party]?此行刪掉。此宏是網(wǎng)上借用的。

#showtooltip

/use 嫩狼肉排

/use 魔法甜面包

/use 奧特蘭克魔法點(diǎn)心

/stopmacro [nogroup:party]

/run c=string.format("%d", UnitHealth("player")/ UnitHealthMax("player")*100) SendChatMessage(c.."% 面包回血中……", "party",nil, 1)

24.[標(biāo)記]圖標(biāo)編號 0=取消圖標(biāo);1=黃色四角星;2=橙色圓形;3=紫色菱形;4=綠色三角;5=白色月亮;6=藍(lán)色方塊;7=紅色叉子;8=骷髏

/script SetRaidTarget("target",圖標(biāo)編號);

*說明：可以自己根據(jù)情況將標(biāo)記宏加入到技能里。比如懺悔加個(gè)星星，制裁加個(gè)菱形，審判加個(gè)骷髏。適合5人10人小隊(duì)使用。

初次使用/script命令會(huì)有安全警告，忽略即可，絕對安全。

再分享一些比較實(shí)用的命令：

[聊天窗口顯示職業(yè)顏色]0顯示/1不顯示?/console SET chatClassColorOverride "0"?根據(jù)聊天判斷職業(yè)，方便加BUFF

[死亡灰色特效]0關(guān)閉/1開啟?/console ffxDeath 0?死亡釋放以后會(huì)有灰色特效，陰森恐怖死氣沉沉。關(guān)閉以后一切又恢復(fù)五彩繽紛、生機(jī)勃勃。

[重置副本]?/run ResetInstances()?刷副本常用命令，再加入喊話，方便快捷。

[隱藏動(dòng)作條兩邊獅鷲]?左/右?/script MainMenuBarLeftEndCap:Hide() /script MainMenuBarRightEndCap:Hide()

[最大鏡頭距離]1-2.6?/console CameraDistanceMaxZoomFactor 2.6

[改TAB距離]身前/身后 0-50碼?/console SET targetNearestDistance "50" /console SET targetNearestDistanceRadius "50"

小編推薦：

>>>《魔獸世界懷舊服》各職業(yè)宏大全

最新資訊
團(tuán)本納克薩瑪斯任務(wù)大全	NAXX攻略專區(qū)	納克薩瑪斯首領(lǐng)攻略大全	納克薩瑪斯物品掉落大全
熱門資訊
納克薩瑪斯法師畢業(yè)裝備參考	納克薩瑪斯狂怒戰(zhàn)畢業(yè)裝備參考	納克薩瑪斯防戰(zhàn)畢業(yè)裝備參考	納克薩瑪斯劍專精賊畢業(yè)裝備參考
納克薩瑪斯匕首專精賊畢業(yè)裝備參考	盜賊開鎖技能1-300升級攻略	碎裂白骨戰(zhàn)斧屬性簡介	帝殞屬性簡介
蛛魔制奴者屬性簡介	薩菲隆的精華屬性簡介	NAXX克爾蘇加德故事背景	NAXX大領(lǐng)主莫格萊尼故事背景